Geçici dosyaları bir tıkla temizleyen Vbscript


Geçici dosyaları bir tıkla temizleyin
Temp (yani geçici) dosyalar sistemimizde oldukça hızlı çoğalan dosyalardır ve bunların temizliği için de çoğu zaman programlar kullanılır (mesela Ccleaner) gel gelelim Ne Ccleaner nede diğerleri etkili bir temizlik


yapamamaktadırlar , başta inandırıcı gibi gelmesede bu yazımızda verdiğimiz vbs scriptini kullanmadan önce CCleaner veya benzeri bir program kullandıktan sonra yazının sonunda yeralan linkten geçici dosya (Temp) temizliği için verdiğimiz dosyayı indirip çalıştırmanızla birlikte temizlenen dosya sayısına sizde şaşıracaksınız. Kodlayanı "Michael Harris" olan Vbs scriptini uzun bir süreden beridir kullanıyorum hem ek program gerektirmemesi hem kurulum gerektirmemesi hemde etkili olması sebebi ile çevrendekilere de tavsiye ettiğim bu scripti sizlerle de paylaşmak istedim , scripti masaüstünüzde bulundurup hergün çalıştırabilirsiniz.

Bir tıkla Tüm geçici (Temp) dosyaları temizleyin

Sayfa sonundaki linkten indireceğiniz "DeleteTempFiles" zip dosyasını zipten çıkartın ve içerisindeki DeleteTempFiles.vbs dosyasını çalıştırın ilk ekranda size silinecek geçici dosya sayısını gösterecektir.

vbs ile geçici dosyaları sil

Tamam butonuna bastığımızda da bulunan (silinecek olan) dosya sayısını ve bunlardan kaçının silindiğini bize bildirir.

silinen geçici dosya sayısı

Aklınıza neden hepsini silmiyor sorusu gelebilir , çünkü ; bazı dosyalar o anda kullanımdadır mesela ben genelde Portable uygulamalar kullanırım ve  scripti çalıştırdığımda onlara ait ve kullanımda birçok geçici dosya bulunuyordu. Toplam 55 satırdan oluşan kodları Aşağıda paylaşıyorum , dileyen kopyalayıp Not defterine yapıştırır ve bir isim verdikten sonra uzantısı .vbs olacak şekilde kaydeder. Lakin hata yapmamak için sayfa sonundaki linkten indirmenizi tavsiye ederim.

'===DeleteTempFiles.vbs===
 'from Michael Harris
 'Edited By BlueLife
On Error Resume Next
Const TemporaryFolder = 2 'for GetSpecialFolder
set fso = createobject("scripting.filesystemobject")

arFiles = array()
count = -1

tempdir = fso.GetSpecialFolder(TemporaryFolder)

SelectFiles tempdir
msgbox count+1 & " files found"

dcount = 0
for each file in arFiles
	on error resume next
	file.delete true
	if err.number = 0 then dcount = dcount + 1
	err.clear
	on error goto 0
next

DeleteEmptyFolders tempdir,false

msgbox count+1 & " files found, " & dcount & " deleted."
sub SelectFiles(sPath)
	On Error Resume Next
	set folder = fso.getfolder(sPath)
	set files = folder.files
	for each file in files
		count = count + 1
		redim preserve arFiles(count)
		set arFiles(count) = file
	next
	for each fldr in folder.subfolders
		SelectFiles fldr.path
	next
	end sub
sub DeleteEmptyFolders(sPath,bDeleteThisFolder)
	On Error Resume Next
	set folder = fso.getfolder(sPath)
	for each fldr in folder.subfolders
		DeleteEmptyFolders fldr.path,true
	next

	if (folder.files.count = 0) and _
		(folder.subfolders.count) = 0 and _
		bDeleteThisFolder then
		folder.delete
		exit sub
	end if
end sub
'===script-sonu===

Eğer sisteminizde daha derinlemesine bir temizlik istiyorsanız Buradaki scriptten faydalanabilrsiniz.

- Windows içerisindeki gizli çöpleri temizleyin Burada

- Bat dosyası ile Çöp temizliği Burada

31 Mayıs 2016 Tarihli başlık güncellendi


26 Yorum Var
  1. Avatar for Velociraptor
  2. Avatar for burak

Yorum Ekle

E-posta hesabınız yayımlanmayacak.

Captcha