Windowslarda güvenlik yada SP yamalari yüklendikce ismi Uninstall ile baslayan klasörler olustururlar , eger HDD inizden yer kazanmak istiyor ve bunlari silmenin sisteminize olumsuz bir etkişinin olup

olmayacagini aklinizdan geciriyorsaniz , aşağıdaki scripten faydalanabilirsiniz (Xp de denenmistir) , bu script ile bu klasörler otomatik olarak silinecektir

If MsgBox("This program will now remove uninstall folders.", _
    vbOkCancel, "Uninstall Remover") = vbOk Then

Set oShell = CreateObject("WScript.Shell")
Set oFSO = CreateObject("Scripting.FileSystemObject")
sWinDir = oFSO.GetSpecialFolder(0)
Set oFolder = oFSO.GetFolder(sWinDir)
Set oDictionary = CreateObject("Scripting.Dictionary")

For Each oSubFolder In oFolder.SubFolders

  sFolderName = LCase(oSubFolder.Name)
  sFolderPath = LCase(oSubFolder.Path)

  If     Left(sFolderName, 13) = "$ntuninstallq" _
      Or Left(sFolderName, 14) = "$ntuninstallkb" Then

    ' Get the update name for the registry delete:

    sUpdateName = Mid(sFolderName, 13, Len(sFolderName) - 13)

    ' Never delete folders/files while enumerating a file/folder collection.
    ' Adds them to a dictionary object for later handling instead:

    oDictionary.Add sUpdateName, sFolderPath

  End If
Next

sDeleted = ""
For Each sUpdateName In oDictionary.Keys

  sDeleted = sDeleted & vbCrLf & sUpdateName
  sFolderPath = oDictionary.Item(sUpdateName)

  On Error Resume Next

  ' Remove entry in Add/Remove Programs:

  oShell.RegDelete "HKLM\SOFTWARE\Microsoft\Windows\" _
      & "CurrentVersion\Uninstall\" & sUpdateName & "\"
  On Error Goto 0

  ' Delete the unisntall folder:

  oShell.Run "%Comspec% /C RD /S /Q " _
      & Chr(34) & sFolderPath & Chr(34), 0, True
Next

If sDeleted <> "" Then
  'MsgBox "The uninstall data for the following updates has been removed:" _
  '     & vbCrLf & UCase(sDeleted)
  MsgBox oDictionary.Count & " update uninstall folders removed."
Else
  MsgBox "No update uninstall data found."
End If

End If

bu kodları bir notepad e yapıştırıp ve Dosya - Farklı Kaydet... seçeneğine tıklayın

Açılan pencerede herhangi bir isim verin (dosya ismini istediğiniz şekilde düzenleyin ) ve uzantısı .vbs olarak kaydedip çalıştırın